Wie Ihr wisst, kann man damit Setup-Programme paketieren als natives unattended Setup.
"Nativ" bedeutet "natürlich" und bei uns hier, daß wir das Original-Setup des Herstellers verwenden können und dadurch nicht alles erst re-paketieren müßen.
Man kann den Package Robot aber auch für ganz andere Sachen verwenden.
Ich zeige hier mal als Beispiel wie man sich ein Login für ein Forum skripten kann.
Es wird hier die 8er Engine verwendet, die spezielle für Browser und Office optimierte Befehle anbietet.
Das Skript ist als Beispiel gedacht wie man mit dem Package Robot:
- Wir prüfen mit IPA\ ob das Matrix-Forum / das Internet überhaupt verfügbar sind
- Die auf dem System eingestellte Sprache abprüft (ILI)
- Das Betriebssystem absichert (IOS)
- Feststellt welches Programm auf eine bestimmte Endung registriert ist (GEP)
- Alle Fenster eines Programmes schliesst (CAW)
- eine WEB-Site definiert im IE öffnen
- Die Fensterlokalisierung mittels HTV und SCW
- AGR\ und AFO\um Elemente auf einer Seite zu finden
- Parallelrobot gegen PopUps
- Die 8er Engine zur Lokalisierung von Browserelementen mittels AGR und ANT
Die fertige Skript Datei findet Ihr zum Herunterladen als Anlage.
Code: Select all
' +++ Forum_Login_public.rem +++
' Zweck:
' erstellt am: 03.10.2009
' von: Theo Gottwald
'========================
'#SPI:ForceWrite
'#EXE:?pfad
'#INC:vbrun
'#SPI:NoAuto
' Debuging Befehl
' DWP 3
' Zu öffnende URL festlegen
' Zuerst mal evtl. noch im Hitnergrund laufende Robots beenden.
KRM\1
VAR\$$URL=http://forum.matrix42.com
' Insert your Username here
VAR\$$LOG=Dein_Login
' Insert your Password here
VAR\$$PWD=Dein_Passwort
' Windows-Sprache abfragen
NLI\1031
OPR\200,200
SBT\10|Dieses Login-Skript läuft nur auf einem deutschen Windows!$crlf$Das Skript beendet sich nun.
GOTO enx
ELI\
' So fragt man das Betriebssystem ab
NOS\W10
OPR\200,200
SBT\10|Dieses Login-Skript läuft nur unter Windows X10!$crlf$Das Skript beendet sich nun.
GOTO enx
EOS\
' Wir Testen ob der IE der registrierte Browser ist.
GEP\test.htm
VAR\$$REG=$v1$
' Beispiel für eine IF ... ELSE .. .ENDIF Verzweigung
IVC\$$REG|iexplore
GOTO over
ELSE
IVC\$$REG|firefox
SBT\3+|Aha ein Firefox User!
EVC\
' OPR\200,200
' SBT\10|Dieses Login-Skript benötigt den Internet Explorer als registrierten Browser!$crlf$Das Skript beendet sich nun.
' GOTO enx
EVC\
VAR\$$URL=http://forum.matrix42.com
IPA\$$URL|80|5
' Mstrix-Forum ist erreichbar
ELSE
MBX\Matrix42 Forum ist nicht erreichbar.
END\
EPA\
:over
VAR\$$*01=autovervollständigen\&nein\soll dieses kennwort gespeiche
VAR\$$*02=internet explorer\&nein\internet explorer ist momentan
DBC\$$*01<>$$*02
' Alle bereits geöffneten m42 IE-Fenster werden geschlossen.
CAW\ieframe\matrix42&&internet explorer
' Matrix-Site starten im registrierten Browser
EXR\iexplore.exe|$$URL
' Warten bis die Site geladen ist
STW\ieframe\internet explorer|w1224
WII\10
SWP\0,0|1621,1041
IWF\10
SPC\internet explorer_server\*|w30
HTV\$$MYW
ELSE
SBT\10|Dieses Login-Skript benötigt den Internet Explorer als registrierten Browser!$crlf$Das Skript beendet sich nun.
GOTO enx
EWF\
SCW\$$MYW
' Wir suchen nach Benutzername ODER Username (Beispiel für ein Pattern)
AGR\42\Benutzername:&OR:Username\\2
' Textfeld-Inhalt zuerst löschen dann reinschreiben
MED\
MED\
TDL\100
PWK\$$LOG
' Textausgaben macht Windows (Compatible Engine) asynchron daher etwas Wartezeit
TDL\100
SCW\$$MYW
AGR\42\Passwort:&OR:Password\\2
MED\
MED\
TDL\100
PWK\$$PWD
' Auto-Login einschalten
SCW\$$MYW
AFO\44\Mich bei jedem Besu&&tomatisch anmelden \notext\notext\11\\'*0/23/1\'34,35\1272,652
BTC\1
SCW\$$MYW
AGR\43!MOS.\&EXACT:Login&OR:ANmelden
' Aussprung
:enx
@