3 TRICKS für ein WEB-basiertes (Facebook-) Login

Moderator: MVogt

3 TRICKS für ein WEB-basiertes (Facebook-) Login

Beitragvon Theo_Gottwald » 07. Feb 2010, 09:26

Oft will man seine Daten etwas unter die Leute bringen.
Facebook und soziale Netzwerke bieten hierfür eine gute Gelegenheit. Und automatisiert geht natürlich auch.

Das kann aber auch eine Programm-Registrierung sein, die man im Rahmen einer automatischen Installation machen möchte. Egal was - die hier gezeigten Techniken kann man dafür nehmen, wenn es im Internet Explorer stattfinden kann.

Technisch hat sich da einiges geändert seit dem IE 6 und so muß man heute tiefer in die Trickkiste greifen um ein automatisches Login zu machen, das sicher funktioniert. Um diese Tricks geht es nun in diesem Post.

TRICK 1: LOW-LEVEL Keyboard-Simulation
Gewöhnlich nutzt man einfach den SKP\-Befehl (oder SKB\) um etwas in eine Eingabefeld zu schreiben.
Das funktioniert auch um zum Beispiel das Login oder Passwort einzugeben.
Manchmal geht es auch gar nicht. Dann muß man SKT\ oder SKA\ nehmen.
Beide simulieren die Tastatur auf dem untersten Level.

Bei dieser Art Tastatursimulation gibt es - je nach Befehl - Besonderheiten,
Zum Beispiel was "Shift" und "Strg" angeht. Denn auf den Keyboard gibt es ja keine Extra-Knöpfe für große oder kleine Buchstaben. Sondern wenn man einen Großbuchstaben klicken will, muß man eben zuerst SHIFT klicken.

Wichtig ist auch: Manchmal steht jedoch schon etwas in dem Feld.
Zum Beispiel weil der Browser oder ein AddOn sich ein Login oder Passwort gemerkt haben.

Nun will man sichergehen und alles was eventuell schon in dem Eingabefeld steht zu erst löschen.
Manuell würde man eventuell da reinklicken, strg-a (alles Markieren) und dann auf die DEL-Taste.
Und schon ist das Eingabefeld leer.
Das nun mit
Code: Alles auswählen
' alles markieren
SKP\^a
' Backspace (löscht alles)
SKP\{BS}


Zu machen hat früher mal funktioniert. Bei neueren IE unter Windows 10 funktioniert es so einfach nicht mehr.
Also nehmen wir eben die Low Level Keyboard-Befehle KYD\ und KYU\ und simulieren jeden Tastenklick einzeln.
Das sieht so aus:

Code: Alles auswählen
:SelAll
' strg-a
KYD\&H11
KYD\&H41
TDL\150
KYU\&H41
KYU\&H11
RET\
'----------------------------------

:Delete
' Delete
KYD\&H2E
TDL\150
KYU\&H2E
RET\


TRICK 2: Verwendung von Unterprogrammen mit GSB\ und RET\
Dadurch kann man sich bestimmte Sequenzen definieren, und einfach - fast wie einen Befehl - eben mit
Code: Alles auswählen
GSB\Loeschen

oder dergleichen aufrufen.

So ist das Skript lesbar und man muß die gleichen Sequenzen nur einmal schreiben.

TRICK 3: Den Internet Explorer gezielt starten
Das funktioniert übrigens auch mit allen anderen registrierten Anwendungen, wie Office-Programmen etc.
Man muß dazu nur die registrierte Dateiendung der Anwendung nach dem GEP\angeben, in diesem Fall für den IE ist es eben ".mht". Denn ".html" wäre bei mir auf Google-Chrome registriert.

Anmerkung, hierzu hat DS eine Verbesserung für eine kommende MPR-Version angekündigt, so daß mit noch weniger Schreibaufwand gehen wird. Dazu wird es den neuen Befehl "EOP\" geben (Explorer Open Page).

Code: Alles auswählen
GEP\.mht
VAR\$$PAT=$v1$
EXE\$$PAT $$URL


Das Script demonstriert ausserdem noch:
- wie man evtl. bereits vorhandene Eingaben in einem Textfeld löscht
- wie man einen Text lokalisiert und erst in einem zweiten Schritt mit ANT\ das Ziel-Textfeld anfährt.
- Die Verwendung von AGR\ zum Erstellen von vielsprachingen Scripten (hier der Klick auf "Anmelden")
- Die Verwendung des AGR\ Patterns: &OR:

Code: Alles auswählen
'' +++ main_FB-Test_2.rem +++
' Zweck:
' erstellt am: 11.04.2018
' von: Theo Gottwald
'========================
'#SPI:ForceWrite
'#EXE:?path
'#INC:vbrun
'#SPI:NoAuto
'#FDC:Ask

' Schliesst alle ggf. noch offenen IE-Fenster
CAW\ieframe\facebook

' Zum Starten des Browsers verwende ich diese Sequenz,
' da BOP\ den registrierten Browser startet, und das könnte
' ein nicht-IE Browser sei.
'
VAR\$$URL=https://login.facebook.com/login.php?login_attempt=0
GEP\.mht
VAR\$$PAT=$v1$
EXE\$$PAT $$URL

STW\ieframe\internet explorer|w1884
SWP\0,0|1118,901
CAS\1
' Die folgenden Zeilen warten bis die Seite fertig geladen ist
AGR\43\Login&OR:Anmelden&OR:Entrar&OR:Connexion
AGR\42\Bei Facebook anmelden

' Hier werden Login und Passwort definiert
VAR\$$LOG=MyLogin
VAR\$$PWD=MyPWd

SPC\internet explorer_server\*|w222
HTV\$$$$MYW
AGR\42\Bei Facebook anmelden

GSB\Locate
SKP\$$LOG

GSB\Locate
SKB\$$PWD

SCW\$$MYW
' Deu & Engl & span & Franz
AGR\43\Login&OR:Anmelden&OR:Entrar&OR:Connexion
MLC\

END\
'----------------------------------
:Locate
SCW\$$MYW
ANT\d|4|42
MLC\
TDL\100
GSB\Select_all
RET\
'----------------------------------
:Select_all
MLI\
GSB\SelAll
TDL\50
GSB\Delete
TDL\50
RET\
'----------------------------------

:SelAll
' strg-a
KYD\&H11
KYD\&H41
TDL\150
KYU\&H41
KYU\&H11
RET\
'----------------------------------

:Delete
' Delete
KYD\&H2E
TDL\150
KYU\&H2E
RET\
'----------------------------------
@



Das Script ist unter Windows 10 mit dem IE11 aufgezeichnet.
Zuletzt geändert von Theo_Gottwald am 01. Jun 2018, 09:57, insgesamt 5-mal geändert.
Benutzeravatar
Theo_Gottwald
 
Beiträge: 291
Registriert: 03. Okt 2009, 08:57
Wohnort: Herrenstr.11 * 76706 Dettenheim

Re: 3 TRICKS für ein WEB-basiertes (Facebook-) Login

Beitragvon Theo_Gottwald » 11. Apr 2018, 09:52

Hab das heute upgedated auf Stand 2018.
Benutzeravatar
Theo_Gottwald
 
Beiträge: 291
Registriert: 03. Okt 2009, 08:57
Wohnort: Herrenstr.11 * 76706 Dettenheim


Zurück zu Package Robot

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 1 Gast